Cara Merangking Di Excel

Cara Mencari Ranking Dengan Ms Docx

Cara Mengurutkan Nilai atau Nama Sesuai Ranking Secara Otomatis

Rumus Excel tentang cara mengurutkan nilai tertinggi ke terendah di excel dan mengurutkan angka atau nama sesuai dengan ranking secara otomatis pada microsoft excel

Setidaknya kami sudah menyajikan empat tutorial excel tentang peringkat nilai atau rangking Excel. Tutorial tersebut antara lain: Setelah berhasil membuat Ranking atau peringkat, masalah yang kemudian muncul adalah bagaimana cara mengurutkan ranking atau peringkat excel tersebut secara otomatis.

Hal ini dimaksudkan untuk mengurutkan nama sesuai ranking di excel sesuai urutan ranking di excel. Cara mengurutkan ranking yang akan saya bahas kali ini sebenarnya tidak hanya bisa diterapkan untuk mengurutkan ranking atau peringkat saja, namun juga bisa digunakan untuk mengurutkan nilai tertinggi ke nilai terendah di excel juga.

Setidaknya ada dua cara untuk mengatasi permasalahan ini. Pertama dengan menggunkan fitur Sort & Filter Excel. Kedua adalah dengan menggunakan rumus Excel atau excel formula.

Pada tutorial kali ini data seperti pada gambar dibawah ini yang akan kita jadikan contoh.

Pada contoh ini, cell G2 berisi rumus perankingan/pemeringkatan sebagai berikut:

=RANK.EQ(F2;$F$2:$F$11;0)+COUNTIF($F$1:F1;F2)

Kemudian copy-pastekan rumus tersebut sampai cell G11.

Cara Mengurutkan Ranking Di Excel Dengan Fitur SORT & FILTER

Cara berikut bisa juga digunakan untuk mengurutkan angka di excel. Ikuti langkah-langkah berikut untuk mengurutkan nama sesuai dengan nilai atau Ranking di excel dengan menggunakan fitur sort & filter:

Seleksi seluruh tabel yang akan kita urutkan.
Pilih TAB "Data" Kemudian pilih menu Filter.
Setelah muncul tombol filter pada masing-masing kolom, pilih tombol filter pada kolom "Ranking"
Kemudian pilih "Sort Smallest to Largest".
Selesai.

Hasil pengurutan dengan cara ini adalah sebagai berikut:

Setelah nama-nama pada tabel tersebut terurut sesuai rankingnya anda bisa melakukan copy paste hasil pengurutan peringkat tersebut pada file atau sheet lain sesuai kebutuhan.

Kelemahan cara ini tentu saja anda harus melakukan sortir atau pengurutan berulang kali jika nilai-nilai yang ada pada data tersebut belum final. Artinya setiap ada perubahan data, anda harus melakkan pengurutan (sortir) secara manual.

Jika anda menghendaki pengurutan ranking secara otomatis lakukan cara kedua dibawah ini.

Cara Mengurutkan Nilai/Ranking di Excel Dengan Rumus Excel

Selain menggunakan fitur Sort, Anda bisa juga menggunakan rumus excel untuk melakukan pengurutan nilai atau rangking secara otomatis.

Cara mengurutkan nama sesuai ranking dengan rumus excel ini tentunya tidak bisa diterapkan pada tabel yang sama. Jadi hasil pengurutan harus pada tabel yang lain. Untuk itu sebelum melakukan pengurutan buatlah sebuah tabel yang sama persis dengan tabel yang perankingan. Untuk contoh diatas tabel bantu yang saya buat seperti ini:

Untuk mengurutkan nama sesuai ranking yang telah kita buat fungsi excel yang akan kita butuhkan adalah fungsi INDEX, fungsi MATCH dan fungsi SMALL.

Jika tabel tempat hasil pengurutan sudah anda buat, untuk contoh diatas tuliskan rumus berikut pada sel J2:

=INDEX($A$2:$G$11;MATCH(SMALL($G$2:$G$11;I2);$G$2:$G$11;0);2)

Untuk sel K2 tuliskan rumus excel berikut:

=INDEX($A$2:$G$11;MATCH(SMALL($G$2:$G$11;I2);$G$2:$G$11;0);3)

Untuk sel L2 tuliskan rumus excel berikut :

=INDEX($A$2:$G$11;MATCH(SMALL($G$2:$G$11;I2);$G$2:$G$11;0);4)

Untuk sel M2 tuliskan rumus excel berikut:

=INDEX($A$2:$G$11;MATCH(SMALL($G$2:$G$11;I2);$G$2:$G$11;0);5)

Untuk sel N2 tuliskan rumus excel berikut:

=SUM(K2:M2)

Untuk kolom ini saya menggunakan fungsi SUM untuk memastikan bahwa hasil pengurutan sudah benar. Selain mengggunakan fungsi SUM seperti diatas anda juga bisa menggunakan rumus excel berikut agar sama seperti kolom-kolom yang lain:

=INDEX($A$2:$G$11;MATCH(SMALL($G$2:$G$11;I2);$G$2:$G$11;0);6)

Untuk sel O2 tuliskan rumus excel berikut:

=INDEX($A$2:$G$11;MATCH(SMALL($G$2:$G$11;I2);$G$2:$G$11;0);7)

Jika rumus-rumus excel tersebut sudah anda tuliskan pada masing-masing kolom lakukan copy paste secara manual atau menggunakan auto fill data untuk sel-sel dibawahnya. Dan hasil akhirnya seperti dibawah ini:

Untuk cara kerja rumus-rumus excel ini sebagai berikut

Cara Kerja Rumus Excel Pengurutan Nilai

Sekarang kita akan bahas cara kerja rumus pengurutan ranking excel diatas. untuk pembahasan ini saya akan ambil salah satu rumus, yakni pada kolom J2:

=INDEX($A$2:$G$11;MATCH(SMALL($G$2:$G$11;I2);$G$2:$G$11;0);2)

Rumus dasar yang kita gunakan untuk pengurutan ranking diatas adalah fungsi INDEX. Fungsi INDEX excel untuk malakukan lookup atau pencarian berdasarkan informasi kolom dan baris tertentu pada sebuah tabel data atau array. Sintaks fungsi index adalah:

INDEX(Sumber_Data; Nomor_Baris; Nomor_Kolom)

Pada kasus diatas:

Sumber_Data: $A$2:$G$11
Nomor_Baris: MATCH(SMALL($G$2:$G$11;I2);$G$2:$G$11;0)
Nomor_Kolom: 2

Seperti yang kita lihat, untuk mencari nomor baris (row_num) kita memanfaatkan fungsi MATCH Excel untuk mendapatkan nilai posisi baris yakni posisi rank 1 pada kasus ini. Sintaks Fungsi MATCH adalah:

MATCH(Nilai_yang_DiCari; Sumber_Pencarian; Tipe_Kecocokan)

Dengan :

Nilai_yang_DiCari: SMALL($G$2:$G$11;I2)
Sumber_Pencarian: $G$2:$G$11
Tipe_Kecocokan: 0 (exact match/sama persis)

Pada rumus di atas kita menggunakan fungsi SMALL Excel untuk mencari urutan terkecil atau ke-1 (I2) dari ranking. sedangkan pada sel J3 kita mencari urutan terkecil ke-2 (I3). begitu seterusnya.

Pada kasus lain mungkin anda akan membutuhkan fungsi LARGE. misalaknya yang akan kita urutkan bukan ranking namun berdasarkan nilai terbesar ke terkecil.

Masing-masing fungsi excel pada rumus excel ini sudah saya bahas pada tutorial belajar excel sebeumnya. untuk lebih detailnya silahkan baca masing-masing artikel tersebut.

Demikian cara mengurutkan nama atau nilai berdasarkan ranking Excel yang bisa saya sampaikan. Silahkan samapaikan di kolom komentar jika masih ada yang belum jelas.